@echo off

REM $Id: run.bat,v 1.2 2003/03/03 06:30:19 aslom Exp $
REM
REM REQUIRED: Please make sure that JAVA_HOME points to JDK1.3+
REM   and make sure that JAVA_HOME\lib contains tools.jar !!!!
REM 

REM JAVA_HOME can be set manualy ..
REM set JAVA_HOME=c:\jdk13

if "%JAVA_HOME%" == "" goto javahomeerror

REM 
REM No need to modify anything after this line.
REM --------------------------------------------------------------------

echo JAVA_HOME=%JAVA_HOME%

set OLDCLASSPATH=%CLASSPATH%
call classpath.bat run quiet

REM set JAVA_OPTS=-DDebug
REM set JAVA_OPTS=-Dlog.names=
REM set JAVA_OPTS="%JAVA_OPTS%"

set OLD_JAVA_ARGS=%JAVA_ARGS%
if "%JNDI_CTX%" == "" goto noEventsCtx
set JAVA_ARGS=-ctx "%JNDI_CTX%" %JAVA_ARGS%
:noEventsCtx


set NAME=%1
shift

set OLDJAVA=%JAVA%
set JAVA=%JAVA_HOME%\bin\java %JAVA_OPTS% %JAVA_DEBUG_OPTS% -cp %LOCALCLASSPATH% 

if "%NAME%" == "monitor" (
   set CMD=%JAVA% SimpleMessageMonitor %JAVA_ARGS% %1 %2 %3 %4 %5 %6 %7 %8 %9
) else if "%NAME%" == "junit" (
   set CMD=%JAVA% junit_tests.PackageTest %JAVA_ARGS% %1 %2 %3 %4 %5 %6 %7 %8 %9
) else (
  set CMD=%JAVA% %NAME% %JAVA_ARGS% %1 %2 %3 %4 %5 %6 %7 %8 %9
)

rem clean up

set CLASSPATH=%OLDCLASSPATH%
set JAVA=%OLDJAVA%
set JAVA_ARGS=%OLD_JAVA_ARGS%
set OLDCLASSPATH=
set OLDJAVA=
set OLD_JAVA_ARGS=

rem exute it

echo %CMD%
%CMD%

goto end

REM -----------ERROR-------------

:javahomeerror
echo "ERROR: JAVA_HOME not found in your environment."
echo "Please, set the JAVA_HOME variable in your environment to match the"
echo "location of the Java Virtual Machine you want to use."


:end